Нужно читать хеш из файла

[бУРов]

Есть файл с записями

data
{
ключ1 = значение
ключ2 = значение
...
ключN = значение
}
...

Нужно считывать записи между скобками в хеш. Есть ли в Perl какая-нибудь функция или нужно циклы делать и проверки - все ручками?

[RXL]

Ручками. Все универсальные инструменты требуют работы ручками. Это правило.

Но, существует понятие библиотек. Если найдешь, как данный формат называется, то в CPAN (www.cpan.org) можно попробовать найти готовый модуль для работы с ним.

На случай, если модуля нет. Обработка таких иерархических структур делается обычным конечным автоматом. Если используется только один уровень (внутри "blockname {  }" нет вложенных таких же блоков), то нужно найти идентификатор и следующее за ним открытие блока "{", после разделить пары "name = value" и найти конец блока "}". Если вложенность есть, то в алгоритм добавляется рекурсия.

[бУРов]

Спасибо. Нет, вложенности нет.

[RXL]

Алгоритм понятен?

[бУРов]

Да, спс. Но я тут нашел интересную возможность. Попробовать использовать переменную

Код:

$/ = "}\n";

Чтобы строка была многострочной и читать весь хеш сразу. Не знаю, что получится.

Код:

while (<>) {
	...
	chop;		# отрезать "}"
	...
	}

[RXL]

бУРов, совсем не рекомендую так поступать. Если хочется использовать подобную логику, то считай файл целиком в скаляр и далее реж регулярными выражениями.

Функцию chop вообще рекомендую забыть - это небезопасный атавизм.

[бУРов]

> совсем не рекомендую так поступать
А почему. Файл сильно большой. Может быть целый гиг.

Добавлено через 21 минуту и 17 секунд:
Можно еще искать строки с "=", и читать их по счетчику (количество пар в хеше известно).

[RXL]

Опасность в том, что $/ — глобальная переменная и будет влиять на все операции с файлами.

Конфиг размером с гиг? Тогда делай так:

Код:

{
    local $/ = "}\n";

    while (<>)
    {
        local $/ = "\n";
        # .....
    }
}

Первый local гарантирует, что при выходе из блока значение $/ восстановится. Второй local создает стандартную настройку внутри while и всех вызванных оттуда подпрограмм.

[бУРов]

Конфиг размером с гиг?

Не конфиг, файл данных.

Тогда делай так:

Да, это то, что нужно!

[RXL]

Наверно даже лучше так:

Код:

{
    my $save_RS = $/;
    local $/ = "}\n";

    while (<>)
    {
        local $/ = $save_RS;
        # .....
    }
}

Потому как дефолтное значение $/ может отличаться для разных платформ.

[бУРов]

Почему для $/ local, а не my?

[RXL]

Почитай, чем отличаются my и local.

Если кратно, то:
my - объявление локальных переменных. Лексическая область видимости: текущий блок и все вложенные.
local - объявление глобальных переменных и сохранение предыдущего состояния. Динамическая область видимости: до следующего local или до выхода из текущего блока.

Переменная $/ является глобальной.

[бУРов]

А еще до сих пор не вьеду, если обьявлять переменную без my (local), это что будет?

типа так:

Код:

$var = 1;

[RXL]

Вот тебе пример для понимания local. Кстати, $_ тоже глобальная переменная.

Код:

sub print_
{
  print "$_\n";
}

$_ = 1;
print_;

{
  local $_ = 2;
  print_;

  {
    local $_ = 3;
    print_;
  }

  print_;
}

print_;

my - обычные локальные переменные.

А еще до сих пор не вьеду, если обьявлять переменную без my (local), это что будет?

типа так:

Код:

$var = 1;

В зависимости от режима строгости.
Если локальная переменная существует, то ей присваивается новое значение.
Если локальной нет, но есть глобальная, то ей присваивается новое значение.
Если нет глобальной и режим строгого синтаксиса (strict) отключен, то создается глобальная переменная.
Если нет глобальной и режим строгого синтаксиса включен, то выдается фатальная ошибка.

Вывод: всегда используй use strict.

Добавь себе в изучение еще слово "our" - объявление глобальных переменных.

Код:

use strict;

my $var = 1;

{
  local $var = 2; # Ошибка! Глобальная переменная не объявлена ранее.
  print "$var\n";
}

print "$var\n";

Код:

use strict;

our $var = 1;

{
  local $var = 2;
  print "$var\n";
}

print "$var\n";

На понимание локальных переменных:

Код:

use strict;

my $var = 1;

{
  $var = 2;
  print "$var\n";
}

print "$var\n";

Код:

use strict;

my $var = 1;

{
  my $var = 2;
  print "$var\n";
}

print "$var\n";