Количество элементов списка в ФормеВыбора

[Marta_Li]

Хочется узнать количество элементов справочника, отобранных перед открытием ФормыВыбора:

Код:

		мЭлемент = ЭлементыФормы.РеестрДолжников.Колонки.ДоговорКонтрагента.ЭлементУправления;
		ФормаВыбора = Справочники.ДоговорыКонтрагентов.ПолучитьФормуВыбора(,мЭлемент.Значение);       
		//Отбор по Контрагенту (Владельцу): 
		ФормаВыбора.ПараметрОтборПоВладельцу = Элемент.Значение;
		ФормаВыбора.ЭлементыФормы.СправочникСписок.НастройкаОтбора.Владелец.Доступность = Ложь;
		//Отбор по ВидуДоговора:
		ФормаВыбора.СправочникСписок.Отбор.ВидДоговора.ВидСравнения                        = ВидСравнения.Равно;
		ФормаВыбора.СправочникСписок.Отбор.ВидДоговора.Значение                            = Перечисления.ВидыДоговоровКонтрагентов.СПокупателем;
		ФормаВыбора.СправочникСписок.Отбор.ВидДоговора.Использование                       = Истина;
		ФормаВыбора.ЭлементыФормы.СправочникСписок.НастройкаОтбора.ВидДоговора.Доступность = Ложь;
		//Отбор по Организации:
		ФормаВыбора.СправочникСписок.Отбор.Организация.Значение                            = Организация;
		ФормаВыбора.СправочникСписок.Отбор.Организация.Использование                       = Истина;
		ФормаВыбора.СправочникСписок.Отбор.Организация.ВидСравнения                        = ВидСравнения.Равно;
		ФормаВыбора.ЭлементыФормы.СправочникСписок.НастройкаОтбора.Организация.Доступность = Ложь;
			
		ТекСтрока.ДоговорКонтрагента = ФормаВыбора.ОткрытьМодально();

Вот перед открытием формы и надо узнать, сколько предлагается для выбора, т.к. если 1, то просто присваивать значение и не нужно открывать форму.
Может, кто подскажет? Спасибо.

[Dest]

Код:

	Запр = Новый Запрос("ВЫБРАТЬ
	                    |	КОЛИЧЕСТВО(*) КАК КоличествоЗаписей
	                    |ИЗ
	                    |	Справочник.ДоговорыКонтрагентов КАК ДоговорыКонтрагентов
	                    |ГДЕ
	                    |	(НЕ ДоговорыКонтрагентов.ПометкаУдаления)
	                    |	И ДоговорыКонтрагентов.Организация = &Организация
	                    |	И ДоговорыКонтрагентов.ВидДоговора = &ВидДоговора
	                    |	И ДоговорыКонтрагентов.Владелец = &Владелец");
						
	Запр.УстановитьПараметр("Организация", Организация);
	Запр.УстановитьПараметр("ВидДоговора", ВидДоговора);
	Запр.УстановитьПараметр("Владелец", Владелец);
	
	ВыборкаКоличесво = Запр.Выполнить().Выбрать();
	
	Пока ВыборкаКоличесво.Следующий() Цикл
		Количество = ВыборкаКоличесво.КоличествоЗаписей;		
	КонецЦикла;
	
	Если Количество = 1 Тогда
		
		Запр.Текст = "ВЫБРАТЬ
		|	ДоговорыКонтрагентов.Ссылка КАК Договор
		|ИЗ
		|	Справочник.ДоговорыКонтрагентов КАК ДоговорыКонтрагентов
		|ГДЕ
		|	(НЕ ДоговорыКонтрагентов.ПометкаУдаления)
		|	И ДоговорыКонтрагентов.Организация = &Организация
		|	И ДоговорыКонтрагентов.ВидДоговора = &ВидДоговора
		|	И ДоговорыКонтрагентов.Владелец = &Владелец";
		
		Выборка = Запр.Выполнить().Выбрать();
		Пока Выборка.Следующий() Цикл
			ТекСтрока.ДоговорКонтрагента = Выборка.Договор;
		КонецЦикла;	
	Иначе
		//Окрываем форму выбора
		
	КонецЕсли;