Создание табличной части. 1с v8

[ZxKill]

Есть такая процедура:

Код:

	Запрос=Новый Запрос;
	Запрос.Текст =
	"ВЫБРАТЬ
	|	РасчетПенсии.Контрагент,
	|	РасчетПенсии.Пенсия,
	|	НакопленияКонтрагентовОстатки.Контрагенты,
	|	НакопленияКонтрагентовОстатки.СуммаОстаток
	|ИЗ
	|	Документ.РасчетПенсии КАК РасчетПенсии,
	|	РегистрНакопления.НакопленияКонтрагентов.Остатки КАК НакопленияКонтрагентовОстатки ГДЕ Контрагенты=РасчетПенсии.Контрагент";
	Результат = Запрос.Выполнить().Выбрать();
	Выплаты.Очистить();
	Пока Результат.Следующий() > 0  Цикл
		Выплаты.Добавить();
		ЕСЛИ Результат.СуммаОстаток<Результат.Пенсия ТОГДА
			Выплаты.ЗаполнитьЗначения(Результат.Контрагент,"Контрагент");	
			Выплаты.ЗаполнитьЗначения(Результат.Пенсия,"КВыплате");
			Выплаты.ЗаполнитьЗначения(Результат.СуммаОстаток,"ОстатокСчета");
		Иначе	
			Выплаты.ЗаполнитьЗначения(Результат.Контрагент,"Контрагент");
			Выплаты.ЗаполнитьЗначения(Результат.Пенсия,"КВыплате");
			Выплаты.ЗаполнитьЗначения(Результат.СуммаОстаток,"ОстатокСчета");
		КонецЕсли;
	КонецЦикла;  

При ее выполнении в табличную часть добавляются несколько строк, но в каждую одно и то же значение последнего документа.
Подскажите как сделать чтобы в строках были все документы, а не один и тот же.

ЗЫ: и сразу вдогонку  программированием 1с занимаюсь третий день только, по этому почти ничего не знаю. Подскажите, пожалуйста, как-то можно оптимизировать эту процедуру? Больше чем уверен, что в данном виде при большом количестве контрагентов, все будет жутко тормозить

[ZxKill]

прошу прощения. Вместо табличная часть надо было написать табличное поле

[Kivals]

У тебя отсутствует связь между таблицами в запросе (точнее неправильно задана).
Попробуй построить запрос конструктором запроса и обрати внимание на страницу Группировка (появляется когда в запросе 2 и более таблиц)

Ошибочка вышла. Страница не Группировка, а Связи

[ZxKill]

запрос итак построен конструктором.... это все дело отлично работает, если выводить в текстовое поле.

Код:

	Запрос=Новый Запрос;
	Запрос.Текст =
	"ВЫБРАТЬ
	|	РасчетПенсии.Контрагент,
	|	РасчетПенсии.Пенсия,
	|	НакопленияКонтрагентовОстатки.Контрагенты,
	|	НакопленияКонтрагентовОстатки.СуммаОстаток
	|ИЗ
	|	Документ.РасчетПенсии КАК РасчетПенсии,
	|	РегистрНакопления.НакопленияКонтрагентов.Остатки КАК НакопленияКонтрагентовОстатки ГДЕ Контрагенты=РасчетПенсии.Контрагент";
	Результат = Запрос.Выполнить().Выбрать();
	ПолеСписка1.Очистить();	
	Пока Результат.Следующий() > 0  Цикл
		ЕСЛИ Результат.СуммаОстаток<Результат.Пенсия ТОГДА
			ПолеСписка1.Добавить(Строка(Результат.Контрагент) + Символы.Таб + " - недостаточно средств");	
		Иначе	
			ПолеСписка1.Добавить(Строка(Результат.Контрагент) +Символы.Таб+Строка(Результат.Пенсия) +Символы.Таб+ Строка(Результат.СуммаОстаток));		
		КонецЕсли;
	КонецЦикла; 

а вот если в табличку то криво получается

[Kivals]

А, ты в этом смысле
на самом деле запрос будет правильным когда у тебя контрагент присутствует и в регистре сведений, и в отобранных документах. Если он присутсвует только в каком-то одном месте - то такие строки тебе не вернуться твоим запросом.

А ошибка у тебя в том, что Выплаты.Добавить(); возвращает ссылку на новую строку (а ты ее игнорируешь) и метод ЗаполнитьЗначения действительно заполняет все строки одним значением (читай внимательно помощь)

[ZxKill]

ничего так и не получается.... 
Я не прошу за меня код писать, если можно напишите простой пример программного заполнения табличного поля 

[ZxKill]

все разобрался, спасибо за правильное направление:)

Код:

Пока Результат.Следующий() > 0  Цикл
		НовСтрока = Выплаты.Добавить();
		//Выплаты.ВыбратьСтроку(НовСтрока);
		ЕСЛИ Результат.СуммаОстаток<Результат.Пенсия ТОГДА
			НовСтрока.Контрагент=Результат.Контрагент;
			//Выплаты.ЗаполнитьЗначения(Результат.Контрагент,"Контрагент");	
			//Выплаты.ЗаполнитьЗначения(Результат.Пенсия,"КВыплате");
			//Выплаты.ЗаполнитьЗначения(Результат.СуммаОстаток,"ОстатокСчета");
		Иначе
			НовСтрока.Контрагент=Результат.Контрагент;
			//Выплаты.ЗаполнитьЗначения(Результат.Контрагент,"Контрагент");
			//Выплаты.ЗаполнитьЗначения(Результат.Пенсия,"КВыплате");
			//Выплаты.ЗаполнитьЗначения(Результат.СуммаОстаток,"ОстатокСчета");
		КонецЕсли;

Если что-нибудь подскажете по методам оптимизации, буду очень благодарен. Или хотябы ссылку где можно почитать

[Kivals]

1. А чем у тебя ветки условия отличаются? ЕСЛИ Результат.СуммаОстаток<Результат.Пенсия ТОГДА ...
2. Можно также использовать ТЗ=Результат.Выгрузить();
3. Все-таки по запросу посмотри информацию про СОЕДИНЕНИЕ (JOIN)

[ZxKill]

тут просто не конечный результат:) если сумма остатка меньше то делается пометка что средств для выплаты нет:)
конечный вариант такой:)

Код:

	Запрос=Новый Запрос;
	Запрос.Текст =
	"ВЫБРАТЬ
	|	РасчетПенсии.Контрагент,
	|	РасчетПенсии.Пенсия,
	|	НакопленияКонтрагентовОстатки.Контрагенты,
	|	НакопленияКонтрагентовОстатки.СуммаОстаток
	|ИЗ
	|	Документ.РасчетПенсии КАК РасчетПенсии,
	|	РегистрНакопления.НакопленияКонтрагентов.Остатки КАК НакопленияКонтрагентовОстатки ГДЕ Контрагенты=РасчетПенсии.Контрагент";
	Результат = Запрос.Выполнить().Выбрать();
	Выплаты.Очистить();
	Пока Результат.Следующий() > 0  Цикл
		НовСтрока = Выплаты.Добавить();
		ЕСЛИ Результат.СуммаОстаток<Результат.Пенсия ТОГДА
			НовСтрока.Контрагент=Результат.Контрагент;
			НовСтрока.КВыплате=Результат.Пенсия;
			НовСтрока.ОстатокСчета=Результат.СуммаОстаток;
			НовСтрока.Отметки="Нет средств";
		Иначе
			НовСтрока.Контрагент=Результат.Контрагент;
			НовСтрока.КВыплате=Результат.Пенсия;
			НовСтрока.ОстатокСчета=Результат.СуммаОстаток;
		КонецЕсли;
	КонецЦикла;

ЗЫ спасибо за наставления, пойду поищу инфу про соединения

[Kivals]

Я бы твое Если ... иначе переписал бы так:

Код:

		НовСтрока.Контрагент=Результат.Контрагент;
		НовСтрока.КВыплате=Результат.Пенсия;
		НовСтрока.ОстатокСчета=Результат.СуммаОстаток;
		ЕСЛИ Результат.СуммаОстаток<Результат.Пенсия ТОГДА
			НовСтрока.Отметки="Нет средств";
		КонецЕсли;

ИМХО - так легче читать и править в будующем

[ZxKill]

есть еще небольшой вопросик   сделал с помощью Результат.Выгрузить()

Код:

	Запрос=Новый Запрос;
	Запрос.Текст =
	"ВЫБРАТЬ
	|	РасчетПенсии.Контрагент,
	|	РасчетПенсии.Пенсия,
	|	НакопленияКонтрагентовОстатки.Контрагенты,
	|	НакопленияКонтрагентовОстатки.СуммаОстаток
	|ИЗ
	|	Документ.РасчетПенсии КАК РасчетПенсии,
	|	РегистрНакопления.НакопленияКонтрагентов.Остатки КАК НакопленияКонтрагентовОстатки ГДЕ Контрагенты=РасчетПенсии.Контрагент";
	Результат = Запрос.Выполнить();
	ТабРез=Результат.Выгрузить();
	ТабличнаяЧасть1.Загрузить(ТабРез);

Думаю так будет быстрее работать, но появилась проблемка... как заполнить поле "Отметки" по условию, как было до этого

Код:

	ЕСЛИ Результат.СуммаОстаток<Результат.Пенсия ТОГДА
			НовСтрока.Отметки="Нет средств";	
		КонецЕсли;

ЗЫ: два часа гугла ничего не дали  подскажите как это реализовать и реально ли вообще это?

[Kivals]

Код:

	ТабРез=Результат.Выгрузить();
	ТабРез.Колонки.Добавить("Отметки");
	Для каждого Стр из ТабРез Цикл
		ЕСЛИ Стр.СуммаОстаток<Стр.Пенсия ТОГДА
			Стр.Отметки="Нет средств";
		КонецЕсли;
	КонецЦикла;
	ТабличнаяЧасть1.Загрузить(ТабРез);

[ZxKill]

спасибо огромное за помощь! правда уже реализовал немного другим способом:)
сделал выделение строки цветом, если денег не хватает

Код:

Процедура ТабличнаяЧасть1ПриПолученииДанных(Элемент, ОформленияСтрок)
	Для Каждого ОформлениеСтроки Из ОформленияСтрок Цикл 
		ЗначениеЯчейкиОстаток = ОформлениеСтроки.Ячейки.СуммаОстаток.Значение - ОформлениеСтроки.Ячейки.Пенсия.Значение;
		Если ЗначениеЯчейкиОстаток < 0 Тогда 
			ОформлениеСтроки.ЦветФона = WebЦвета.Красный;  
		КонецЕсли; 
	КонецЦикла; 
КонецПроцедуры

ЗЫ: сохраню на компе Вашу реализацию, пригодится 

[Kivals]

Так нагляднее - однозначно