Основная схема компоновки данных

[staff]

во время формирования отчета ПланФактМТО выводится ошибка:

Код:

Ошибка исполнения отчета
по причине:
Ошибка получения данных
по причине:
Ошибка создания набора данных "НаборДанных1"
по причине:
Ошибка при исполнении запроса набора данных
по причине:
{(33, 57)}: Неверные параметры в операции сравнения. Нельзя сравнивать поля
 неограниченной длины и поля несовместимых типов.
(торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Период <<?>>МЕЖДУ &НачалоПериода И &КонецПериод

Запрос на формирование отчета:

Код:

ВЫБРАТЬ РАЗРЕШЕННЫЕ
	ВЫБОР
		КОГДА торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Номенклатура ЕСТЬ NULL 
			ТОГДА торо_ФактическиеМатериальныеЗатратыРемонтныхРабот.Номенклатура
		ИНАЧЕ торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Номенклатура
	КОНЕЦ КАК Номенклатура,
	СУММА(торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Количество) КАК ПлановоеКоличество,
	СУММА(торо_ФактическиеМатериальныеЗатратыРемонтныхРабот.Количество) КАК ФактическоеКоличество,
	ВЫБОР
		КОГДА торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Регистратор ЕСТЬ NULL 
			ТОГДА торо_ФактическиеМатериальныеЗатратыРемонтныхРабот.Регистратор.ЗаявкаНаРемонт
		ИНАЧЕ торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Регистратор
	КОНЕЦ КАК ЗаявкаНаРемонт,
	ВЫБОР
		КОГДА торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.ID ЕСТЬ NULL 
			ТОГДА торо_ФактическиеМатериальныеЗатратыРемонтныхРабот.ID
		ИНАЧЕ торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.ID
	КОНЕЦ КАК ID,
	(ВЫБОР
		КОГДА торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Номенклатура ЕСТЬ NULL 
			ТОГДА торо_ФактическиеМатериальныеЗатратыРемонтныхРабот.Номенклатура
		ИНАЧЕ торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Номенклатура
	КОНЕЦ).ЕдиницаХраненияОстатков КАК ЕдиницаИзмерения,
	торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Период КАК ПлановыйПериод,
	торо_ФактическиеМатериальныеЗатратыРемонтныхРабот.Период КАК ФактическийПериод
ПОМЕСТИТЬ ЗатратыПланФакт
ИЗ
	РегистрНакопления.торо_ПлановыеМатериальныеЗатратыРемонтныхРабот КАК торо_ПлановыеМатериальныеЗатратыРемонтныхРабот
		ПОЛНОЕ СОЕДИНЕНИЕ РегистрНакопления.торо_ФактическиеМатериальныеЗатратыРемонтныхРабот КАК торо_ФактическиеМатериальныеЗатратыРемонтныхРабот
		ПО торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.ID = торо_ФактическиеМатериальныеЗатратыРемонтныхРабот.ID
			И торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Номенклатура = торо_ФактическиеМатериальныеЗатратыРемонтныхРабот.Номенклатура
ГДЕ
	(торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Период МЕЖДУ &НачалоПериода И &КонецПериод
			ИЛИ торо_ФактическиеМатериальныеЗатратыРемонтныхРабот.Период МЕЖДУ &НачалоПериода И &КонецПериода)

СГРУППИРОВАТЬ ПО
	ВЫБОР
		КОГДА торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Регистратор ЕСТЬ NULL 
			ТОГДА торо_ФактическиеМатериальныеЗатратыРемонтныхРабот.Регистратор.ЗаявкаНаРемонт
		ИНАЧЕ торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Регистратор
	КОНЕЦ,
	ВЫБОР
		КОГДА торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.ID ЕСТЬ NULL 
			ТОГДА торо_ФактическиеМатериальныеЗатратыРемонтныхРабот.ID
		ИНАЧЕ торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.ID
	КОНЕЦ,
	ВЫБОР
		КОГДА торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Номенклатура ЕСТЬ NULL 
			ТОГДА торо_ФактическиеМатериальныеЗатратыРемонтныхРабот.Номенклатура
		ИНАЧЕ торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Номенклатура
	КОНЕЦ,
	(ВЫБОР
		КОГДА торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Номенклатура ЕСТЬ NULL 
			ТОГДА торо_ФактическиеМатериальныеЗатратыРемонтныхРабот.Номенклатура
		ИНАЧЕ торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Номенклатура
	КОНЕЦ).ЕдиницаХраненияОстатков,
	торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Период,
	торо_ФактическиеМатериальныеЗатратыРемонтныхРабот.Период
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	МАКСИМУМ(ЦеныНоменклатуры.Период) КАК ПлановыйПериод,
	МАКСИМУМ(ЦеныНоменклатуры1.Период) КАК ФактическийПериод,
	ЗатратыПланФакт.ЗаявкаНаРемонт,
	ЗатратыПланФакт.ЕдиницаИзмерения,
	ЗатратыПланФакт.Номенклатура,
	Константы.торо_ТипЦеныДляРасчетаСебестоимостиРемонта
ПОМЕСТИТЬ ПлановыйФактическиеПериодыИзРегистра
ИЗ
	ЗатратыПланФакт КАК ЗатратыПланФакт
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры
		ПО ЗатратыПланФакт.ПлановыйПериод >= ЦеныНоменклатуры.Период
			И ЗатратыПланФакт.Номенклатура = ЦеныНоменклатуры.Номенклатура
			И ЗатратыПланФакт.ЕдиницаИзмерения = ЦеныНоменклатуры.ЕдиницаИзмерения
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры1
		ПО ЗатратыПланФакт.ФактическийПериод >= ЦеныНоменклатуры1.Период
			И ЗатратыПланФакт.ЕдиницаИзмерения = ЦеныНоменклатуры1.ЕдиницаИзмерения
			И ЗатратыПланФакт.Номенклатура = ЦеныНоменклатуры1.Номенклатура
		ЛЕВОЕ СОЕДИНЕНИЕ Константы КАК Константы
		ПО (ИСТИНА)

СГРУППИРОВАТЬ ПО
	ЗатратыПланФакт.ЗаявкаНаРемонт,
	ЗатратыПланФакт.ЕдиницаИзмерения,
	ЗатратыПланФакт.Номенклатура,
	Константы.торо_ТипЦеныДляРасчетаСебестоимостиРемонта
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	МАКСИМУМ(ВЫБОР
			КОГДА ЦеныНоменклатуры.Цена ЕСТЬ NULL 
				ТОГДА 0
			ИНАЧЕ ЦеныНоменклатуры.Цена
		КОНЕЦ) КАК ПлановаяЦена,
	МАКСИМУМ(ВЫБОР
			КОГДА ЦеныНоменклатуры1.Цена ЕСТЬ NULL 
				ТОГДА 0
			ИНАЧЕ ЦеныНоменклатуры1.Цена
		КОНЕЦ) КАК ФактическаяЦена,
	ПлановыйФактическиеПериодыИзРегистра.ЗаявкаНаРемонт,
	ПлановыйФактическиеПериодыИзРегистра.Номенклатура
ПОМЕСТИТЬ ЦенаПланФакт
ИЗ
	ПлановыйФактическиеПериодыИзРегистра КАК ПлановыйФактическиеПериодыИзРегистра
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры
		ПО ПлановыйФактическиеПериодыИзРегистра.ПлановыйПериод = ЦеныНоменклатуры.Период
			И ПлановыйФактическиеПериодыИзРегистра.ЕдиницаИзмерения = ЦеныНоменклатуры.ЕдиницаИзмерения
			И ПлановыйФактическиеПериодыИзРегистра.торо_ТипЦеныДляРасчетаСебестоимостиРемонта = ЦеныНоменклатуры.ТипЦен
			И ПлановыйФактическиеПериодыИзРегистра.Номенклатура = ЦеныНоменклатуры.Номенклатура
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры1
		ПО ПлановыйФактическиеПериодыИзРегистра.ФактическийПериод = ЦеныНоменклатуры1.Период
			И ПлановыйФактическиеПериодыИзРегистра.ЕдиницаИзмерения = ЦеныНоменклатуры1.ЕдиницаИзмерения
			И ПлановыйФактическиеПериодыИзРегистра.торо_ТипЦеныДляРасчетаСебестоимостиРемонта = ЦеныНоменклатуры1.ТипЦен
			И ПлановыйФактическиеПериодыИзРегистра.Номенклатура = ЦеныНоменклатуры1.Номенклатура

СГРУППИРОВАТЬ ПО
	ПлановыйФактическиеПериодыИзРегистра.ЗаявкаНаРемонт,
	ПлановыйФактическиеПериодыИзРегистра.ПлановыйПериод,
	ПлановыйФактическиеПериодыИзРегистра.ФактическийПериод,
	ПлановыйФактическиеПериодыИзРегистра.Номенклатура
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ РАЗЛИЧНЫЕ
	ЗатратыПланФакт.Номенклатура,
	ЗатратыПланФакт.ЗаявкаНаРемонт,
	СУММА(ЗатратыПланФакт.ПлановоеКоличество * ЦенаПланФакт.ПлановаяЦена) КАК ПлановаяСумма,
	СУММА(ЗатратыПланФакт.ФактическоеКоличество * ЦенаПланФакт.ФактическаяЦена) КАК ФактическаяСумма,
	СУММА(ЕСТЬNULL(ЗатратыПланФакт.ФактическоеКоличество * ЦенаПланФакт.ФактическаяЦена, 0) - ЕСТЬNULL(ЗатратыПланФакт.ПлановоеКоличество * ЦенаПланФакт.ПлановаяЦена, 0)) КАК СравнениеПланаФакта
ПОМЕСТИТЬ ПланФактМТО
ИЗ
	ЗатратыПланФакт КАК ЗатратыПланФакт
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.торо_ПериодыВыполненияРемонтныхРабот КАК торо_ПериодыВыполненияРемонтныхРабот
			ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.торо_ПериодыВыполненияРемонтныхРабот КАК торо_ПериодыВыполненияРемонтныхРабот1
			ПО торо_ПериодыВыполненияРемонтныхРабот.Родитель_ID = торо_ПериодыВыполненияРемонтныхРабот1.Родитель_ID
		ПО ЗатратыПланФакт.ID = торо_ПериодыВыполненияРемонтныхРабот.ID
		ЛЕВОЕ СОЕДИНЕНИЕ ЦенаПланФакт КАК ЦенаПланФакт
		ПО ЗатратыПланФакт.ЗаявкаНаРемонт = ЦенаПланФакт.ЗаявкаНаРемонт
			И ЗатратыПланФакт.Номенклатура = ЦенаПланФакт.Номенклатура

СГРУППИРОВАТЬ ПО
	ЗатратыПланФакт.Номенклатура,
	ЗатратыПланФакт.ЗаявкаНаРемонт
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ПланФактМТО.Номенклатура КАК Номенклатура,
	ПланФактМТО.ЗаявкаНаРемонт КАК ЗаявкаНаРемонт,
	ВЫБОР
		КОГДА ПланФактМТО.ПлановаяСумма > 0
				И ПланФактМТО.СравнениеПланаФакта / ПланФактМТО.ПлановаяСумма <= 0.1
				И ПланФактМТО.СравнениеПланаФакта / ПланФактМТО.ПлановаяСумма >= -0.1
			ТОГДА "Ремонт выполнен в пределах лимита"
		КОГДА ПланФактМТО.ПлановаяСумма = 0
				ИЛИ ПланФактМТО.СравнениеПланаФакта / ПланФактМТО.ПлановаяСумма < -0.1
			ТОГДА "Превышен лимит"
		ИНАЧЕ "Экономия лимита"
	КОНЕЦ КАК СравнениеПланаФакта,
	1 КАК Количество
ПОМЕСТИТЬ ОтклонениеОтПланаМТО
ИЗ
	ПланФактМТО КАК ПланФактМТО
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ЕСТЬNULL(ОтклонениеОтПланаМТО.Номенклатура, ЗНАЧЕНИЕ(справочник.номенклатура.пустаяссылка)) КАК Номенклатура,
	ЕСТЬNULL(ОтклонениеОтПланаМТО.ЗаявкаНаРемонт, ЗНАЧЕНИЕ(Документ.торо_ЗаявкаНаРемонт.ПустаяСсылка)) КАК ЗаявкаНаРемонт,
	ВложенныйЗапрос.СравнениеПланаФакта КАК Сравнение,
	ЕСТЬNULL(ОтклонениеОтПланаМТО.Количество, 0) КАК Количество 
ИЗ
	(ВЫБРАТЬ
		"Ремонт выполнен в пределах лимита" КАК СравнениеПланаФакта
	
	ОБЪЕДИНИТЬ ВСЕ
	
	ВЫБРАТЬ
		"Превышение лимита"
	
	ОБЪЕДИНИТЬ ВСЕ
	
	ВЫБРАТЬ
		"Экономия лимита") КАК ВложенныйЗапрос
		ЛЕВОЕ СОЕДИНЕНИЕ ОтклонениеОтПланаМТО КАК ОтклонениеОтПланаМТО
		ПО ВложенныйЗапрос.СравнениеПланаФакта = ОтклонениеОтПланаМТО.СравнениеПланаФакта

УПОРЯДОЧИТЬ ПО
	Сравнение

что не хватает запросу для нормального функционирования?

[Kivals]

Судя по тому, что у тебя ПОЛНОЕ СОЕДИНЕНИЕ значение поля Период любого из регистров может быть NULL. Задай лучше это условие в отборе, а не в блоке ГДЕ, т.е. будет где-то так:

Код:

...
ИЗ
	РегистрНакопления.торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Обороты(&НачалоПериода, &КонецПериода, Запись, ) КАК торо_ПлановыеМатериальныеЗатратыРемонтныхРабот
		ПОЛНОЕ СОЕДИНЕНИЕ РегистрНакопления.торо_ФактическиеМатериальныеЗатратыРемонтныхРабот.Обороты(&НачалоПериода, &КонецПериода, Запись, ) КАК торо_ФактическиеМатериальныеЗатратыРемонтныхРабот
		ПО торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.ID = торо_ФактическиеМатериальныеЗатратыРемонтныхРабот.ID
			И торо_ПлановыеМатериальныеЗатратыРемонтныхРабот.Номенклатура = торо_ФактическиеМатериальныеЗатратыРемонтныхРабот.Номенклатура
СГРУППИРОВАТЬ ПО
...

Только еще ко всем Ресурсам регистра в запросе нужно будет добавить слово Оборот: Количество -> КоличествоОборот

[Kivals]

И еще: Конструкции вида

Код:

	ВЫБОР
		КОГДА Значение1 ЕСТЬ NULL 
			ТОГДА Значение2
		ИНАЧЕ Значение1
	КОНЕЦ КАК Значение,

Можно записать проще:

Код:

ЕСТЬNULL(Значение1, Значение2) КАК Значение,

[staff]

Изменения помогли, ошибок нет.
Но сейчас разбираюсь с тем, что не выводятся данные в отчете (((

[Kivals]

Еще раз запости полученный запрос

[staff]

все работает ))), причиной была лишь в том, что документы отвечающие за вывод данного отчета не были созданы.

еще вопрос по печатной форме, есть документ "Акты об оказании производственных услуг" печать документа производится из ФормаСписка
код процедуры:

Код:

Процедура ДействиеПечать(Кнопка)

	Если ЭтаФорма.ЭлементыФормы.Список.ТекущаяСтрока = Неопределено тогда
		Возврат
	КонецЕсли;
	
	УниверсальныеМеханизмы.НапечататьДокументИзФормыСписка(ЭтаФорма.ЭлементыФормы.Список.ТекущаяСтрока.ПолучитьОбъект());
	
КонецПроцедуры

ошибка:

Код:

{Документ.АктОбОказанииПроизводственныхУслуг.Форма.ФормаСписка(11)}: Метод объекта не обнаружен (НапечататьДокументИзФормыСписка)
	УниверсальныеМеханизмы.НапечататьДокументИзФормыСписка(ЭтаФорма.ЭлементыФормы.Список.ТекущаяСтрока.ПолучитьОбъект());

смотрел по идентичной конфигурации как и моя (отличаются только версиями), там такая же самая ошибка (((

[staff]

нашел чего не хватает, сейчас устраняю

[staff]

по вопросу формирования отчета есть функция, я над ней мучаюсь уже 3 дня и не могу домучать ее(((

Код:

Функция ПечатьТребованиеНакладная()

	Запрос = Новый Запрос;
	Запрос.УстановитьПараметр("ТекущийДокумент", ЭтотОбъект.Ссылка);
	Запрос.Текст = 
	"ВЫБРАТЬ
	|	Номер,
	|	Дата,
	|	Организация,
	|	Склад,
	|	"+?(ОтражатьВБухгалтерскомУчете, "ПодразделениеОрганизации", "Подразделение")+" КАК Подразделение
	|ИЗ
	|	Документ.ТребованиеНакладная КАК ТребованиеНакладная
	|
	|ГДЕ
	|	ТребованиеНакладная.Ссылка = &ТекущийДокумент";

	Шапка = Запрос.Выполнить().Выбрать();
	Шапка.Следующий();

	Запрос = Новый Запрос;
	Запрос.УстановитьПараметр("ТекущийДокумент", ЭтотОбъект.Ссылка);
	
	ДопКолонка = Константы.ДополнительнаяКолонкаПечатныхФормДокументов.Получить();
	Если ДопКолонка = Перечисления.ДополнительнаяКолонкаПечатныхФормДокументов.Артикул Тогда
		ТоварКод = "Артикул";
	Иначе
		ТоварКод = "Код";
	КонецЕсли;
	
	Запрос.Текст =
	"ВЫБРАТЬ
	|	МИНИМУМ(НомерСтроки) КАК НомПП,
	|	Номенклатура." + ТоварКод + " КАК Код,
	|	ВЫРАЗИТЬ(Номенклатура.НаименованиеПолное КАК Строка(1000)) КАК Имя,
	|	ХарактеристикаНоменклатуры       	 КАК Характеристика,
	|	ЕдиницаИзмеренияМест КАК ЕдИзмМест,
	|	ЕдиницаИзмерения КАК ЕдИзм,
	|	СУММА(Количество) КАК Количество,
	|	СУММА(КоличествоМест) КАК КоличествоМест
	|
	|ИЗ
	|	Документ.ТребованиеНакладная.Материалы КАК ТребованиеНакладная
	|
	|ГДЕ
	|	ТребованиеНакладная.Ссылка = &ТекущийДокумент
	|
	|СГРУППИРОВАТЬ ПО
	|	Номенклатура,
	|	ЕдиницаИзмерения,
	|	ЕдиницаИзмеренияМест,
	|	ХарактеристикаНоменклатуры
	|
	|УПОРЯДОЧИТЬ ПО
	|	НомПП
	|";

	ЗапросПоНоменклатуре = Запрос.Выполнить();

	ТабДокумент = Новый ТабличныйДокумент;
	ТабДокумент.ИмяПараметровПечати = "ПАРАМЕТРЫ_ПЕЧАТИ_ТребованиеНакладная_ТН";
	
	// Вывод заголовка
	Макет = ПолучитьМакет("ТребованиеНакладная");
	
	// печать производится на языке, указанном в настройках пользователя
	КодЯзыкаПечать = Локализация.ПолучитьЯзыкФормированияПечатныхФорм(УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(глЗначениеПеременной("глТекущийПользователь"), "РежимФормированияПечатныхФорм"));
	Макет.КодЯзыкаМакета = КодЯзыкаПечать;
	
	Область = Макет.ПолучитьОбласть("Заголовок");
	Область.Параметры.ТекстЗаголовка = ОбщегоНазначения.СформироватьЗаголовокДокумента(Ссылка, НСтр("ru='Требование-накладная';uk='Накладна-вимога'",КодЯзыкаПечать),КодЯзыкаПечать);
	Область.Параметры.Заполнить(Шапка);
	ТабДокумент.Вывести(Область);

	ВыборкаПоСтрокам = ЗапросПоНоменклатуре.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);
	Пока ВыборкаПоСтрокам.Следующий() Цикл

		Область = Макет.ПолучитьОбласть("Строка");
		Область.Параметры.Заполнить(ВыборкаПоСтрокам);
		Область.Параметры.Имя = СокрЛП(ВыборкаПоСтрокам.Имя) + ФормированиеПечатныхФорм.ПредставлениеСерий(ВыборкаПоСтрокам);
		ТабДокумент.Вывести(Область);

	КонецЦикла;

	// Вывод подвала
	Область = Макет.ПолучитьОбласть("Подписи");
	ТабДокумент.Вывести(Область);
	
	МестВсего = ЗапросПоНоменклатуре.Выгрузить().Итог("КоличествоМест");
    Если МестВсего = 0 Тогда
		УниверсальныеМеханизмы.СкрытьКолонкиВТабличномДокументе(ТабДокумент, "Мест",2, "Заголовок");
    КонецЕсли;


	Возврат ТабДокумент;

КонецФункции

ошибка

Код:

{Документ.ТребованиеНакладная(285)}: Слишком много фактических параметров
	Область.Параметры.ТекстЗаголовка = ОбщегоНазначения.СформироватьЗаголовокДокумента(Ссылка, НСтр("ru='Требование-накладная';uk='Накладна-вимога'",КодЯзыкаПечать),КодЯзыкаПечать);

что этой функции не хватает??