Условия в запросе

[jonik_joker]

Всем привет.Вопрос:в запросе установлено 2 условия-отбор по клиенту и отбор по дате.Если в форме не заполнить хотя бы один из этих параметров,то сортировка не происходит.Можно ли в самом конструкторе запроса прописать чтобы при незаполнении хотя бы одного  параметра отбор по второму происходил?

[Kivals]

Используй закладку конструктора запроса "Построитель" или "Компоновка данных" (смотря откуда вызываешь)
Тогда такие условия будут в запросе записаны в фигурных скобках и подставляться только при наличии нужного параметра:

Код: (1C v8)

"ВЫБРАТЬ
|       АвансовыйОтчет.Ссылка
|ИЗ
|       Документ.АвансовыйОтчет КАК АвансовыйОтчет
|{ГДЕ
|       АвансовыйОтчет.Проведен = &Проведен}"

Параметр "Проведен" не установлен - отобраны все документы
Параметр "Проведен" = Истина - отобраны только проведенные
Параметр "Проведен" = Ложь - отобраны только НЕ проведенные

[jonik_joker]

я создаю Отчет. В ФормеОтчета прописан запрос

Код: (1C v8)

Запрос.Текст="ВЫБРАТЬ
                     |  ЗаявкаНаПоставку.Дата,
                     |  НАЧАЛОПЕРИОДА(ЗаявкаНаПоставку.Дата, ДЕНЬ) КАК Поле1,
                     |  ОборотыДенежныхСредствОстаткиИОбороты.Клиент,
                     |  ОборотыДенежныхСредствОстаткиИОбороты.Заявка,
                     |  ОборотыДенежныхСредствОстаткиИОбороты.Инвойс,
                     |  ОборотыДенежныхСредствОстаткиИОбороты.СуммаПриход
                     |ИЗ
                     |  Документ.ЗаявкаНаПоставку КАК ЗаявкаНаПоставку
                     |          ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ОборотыДенежныхСредств.ОстаткиИОбороты КАК ОборотыДенежныхСредствОстаткиИОбороты
                     |          ПО ОборотыДенежныхСредствОстаткиИОбороты.Заявка = ЗаявкаНаПоставку.Ссылка
                     |ГДЕ
                     |  НАЧАЛОПЕРИОДА(ЗаявкаНаПоставку.Дата, ДЕНЬ) МЕЖДУ &ДатаНачала И &ДатаКонца
                     |  И ЗаявкаНаПоставку.Клиент = &Клиент";

Как в нем прописать фигурные скобки?

[Kivals]

По правой кнопке на запросе вызываешь "конструктор запроса", идешь в "Построитель - Условия" и добавляешь 2 своих условия:
"НАЧАЛОПЕРИОДА(ЗаявкаНаПоставку.Дата, ДЕНЬ) МЕЖДУ &ДатаНачала И &ДатаКонца"
и "ЗаявкаНаПоставку.Клиент = &Клиент"
(а просто с закладки "условия" их удаляешь)
После этого жмешь Ок и получаешь:

Код: (1C v8)

Запрос.Текст="ВЫБРАТЬ
                     |  ЗаявкаНаПоставку.Дата,
                     |  НАЧАЛОПЕРИОДА(ЗаявкаНаПоставку.Дата, ДЕНЬ) КАК Поле1,
                     |  ОборотыДенежныхСредствОстаткиИОбороты.Клиент,
                     |  ОборотыДенежныхСредствОстаткиИОбороты.Заявка,
                     |  ОборотыДенежныхСредствОстаткиИОбороты.Инвойс,
                     |  ОборотыДенежныхСредствОстаткиИОбороты.СуммаПриход
                     |ИЗ
                     |  Документ.ЗаявкаНаПоставку КАК ЗаявкаНаПоставку
                     |          ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ОборотыДенежныхСредств.ОстаткиИОбороты КАК ОборотыДенежныхСредствОстаткиИОбороты
                     |          ПО ОборотыДенежныхСредствОстаткиИОбороты.Заявка = ЗаявкаНаПоставку.Ссылка
                     |{ГДЕ
                     |  НАЧАЛОПЕРИОДА(ЗаявкаНаПоставку.Дата, ДЕНЬ) МЕЖДУ &ДатаНачала И &ДатаКонца,
                     |  ЗаявкаНаПоставку.Клиент = &Клиент}";

Обрати внимание: вместо "И" в условиях - просто запятая

P.S. Для выделения кода используй [code=e1cv8]...[/code]

[jonik_joker]

прописал, получилось вот так

Код: (1C v8)

|{ГДЕ
                     |  (НАЧАЛОПЕРИОДА(ЗаявкаНаПоставку.Дата, ДЕНЬ) МЕЖДУ &ДатаНачала И &ДатаКонца),
                     |  (ЗаявкаНаПоставку.Клиент = &Клиент)}";

теперь выборка совсем не происходит,выводится все.

[Kivals]

Если у тебя нет строк типа

Код: (1C v8)

Запрос.Параметры.Вставить("ИмяПараметра", ЗначениеПараметра);

То все верно - будет выводиться все, т.е. условия не будут накладываться

[jonik_joker]

Kivals, перед запросом прописано

 

Код: (1C v8)

Запрос.УстановитьПараметр("Клиент",Клиент);
                Запрос.УстановитьПараметр("ДатаНачала",НачалоДня(ДатаНачала));
        Запрос.УстановитьПараметр("ДатаКонца",КонецДня(ДатаКонца));

[Kivals]

Перечитал внимательно про построитель - оказалось что (несмотря на схожесть синтаксиса с "Компоновкой данных") это устаревшая вещь и работать с ней неудобно.
Т.е. так, как я описывал выше, будут работать параметры на закладке "Компоновка данных" - это подходит для динамических списков на форме.

В случае программного использования запроса проще либо
а) сравнивать на пустое значение параметра:

Код: (1C v8)

Запрос.Текст="ВЫБРАТЬ
                     |  ...
                     |ИЗ
                     |  Документ.ЗаявкаНаПоставку КАК ЗаявкаНаПоставку
                     |          ...
                     |ГДЕ
                     |  ((&ДатаНачала = '0001.01.01') ИЛИ (НАЧАЛОПЕРИОДА(ЗаявкаНаПоставку.Дата, ДЕНЬ) МЕЖДУ &ДатаНачала И &ДатаКонца))
                     |  И ((&Клиент = ЗНАЧЕНИЕ(Справочник.Клиенты.ПустаяСсылка)) ИЛИ (ЗаявкаНаПоставку.Клиент = &Клиент))";

б) добавить еще один параметр использования параметра :

Код: (1C v8)

Запрос.Текст="ВЫБРАТЬ
                     |  ...
                     |ИЗ
                     |  Документ.ЗаявкаНаПоставку КАК ЗаявкаНаПоставку
                     |          ...
                     |ГДЕ
                     |  (&ИспользоватьПериод ИЛИ (НАЧАЛОПЕРИОДА(ЗаявкаНаПоставку.Дата, ДЕНЬ) МЕЖДУ &ДатаНачала И &ДатаКонца))
                     |  И (&ИспользоватьКлиент ИЛИ (ЗаявкаНаПоставку.Клиент = &Клиент))";
Запрос.Параметры.Вставить("ИспользоватьПериод", Истина);
Запрос.Параметры.Вставить("ИспользоватьКлиент", Ложь);

P.S. С точки зрения опитимизации времени выполнения лучше вместо

Код: (1C v8)

"НАЧАЛОПЕРИОДА(ЗаявкаНаПоставку.Дата, ДЕНЬ) МЕЖДУ &ДатаНачала И &ДатаКонца"

использовать

Код: (1C v8)

"ЗаявкаНаПоставку.Дата МЕЖДУ &ДатаНачала И &ДатаКонца"

и передавать параметры так:

Код: (1C v8)

Запрос.Параметры.Вставить("ДатаНачала", НачалоДня(ДатаНачала));
Запрос.Параметры.Вставить("ДатаКонца", КонецДня(ДатаКонца));

[jonik_joker]

Ха , интересно , реально логическая лозейка ) спасибо , завтра испробую .
По поводу периода: ЗаявкаНаПоставку.Дата не получится использовать, т.к. дата выводится со временем и сравнения с&ДатаНачала И &ДатаКонца  не происходит.

[Kivals]

По поводу периода: ЗаявкаНаПоставку.Дата не получится использовать, т.к. дата выводится со временем и сравнения с&ДатаНачала И &ДатаКонца  не происходит.

Я же написал как правильно передать параметры в запрос, чтобы время не влияло на отбор - читай внимательней

[jonik_joker]

да, спасибо все получилось. Правда я до конца не понял почему не происходит сравнение по времени.

[Kivals]

да, спасибо все получилось. Правда я до конца не понял почему не происходит сравнение по времени.

Потому что в параметрах тоже данные передаются со времнем, только даже в случае, когда мы передаем одну и ту же дату (например: 01.01.2014) параметр "ДатаНачала" будет равен "01.01.2014 00:00:00", а "ДатаКонца" - "01.01.2014 23:59:59".
Потому что при передаче параметров мы предварительно вызываем функции НачалоДня() и КонецДня()